fish functions and user key bindings

platforms/home-manager/modules/nmasur/presets/programs/git/fish/commandline-git-commits.fish

@@ -0,0 +1,6 @@
+set commit (git-commits)
+if [ $commit ]
+    commandline -i "$commit"
+else
+    commandline -i HEAD
+end

platforms/home-manager/modules/nmasur/presets/programs/git/fish/git-add-fuzzy.fish

@@ -0,0 +1,14 @@
+set gitfile (git status -s \
+    | fzf \
+        --height 50% \
+        -m \
+        --preview-window right:70% \
+        --layout reverse \
+        --preview 'set -l IFS; set gd (git diff --color=always (echo {} | awk \'{$1=$1};1\' | cut -d" " -f2)); if test "$gd"; echo "$gd"; else; bat --color=always (echo {} | awk \'{$1=$1};1\' | cut -d" " -f2); end')
+and for gf in $gitfile
+    set gf (echo $gf \
+        | awk '{$1=$1};1' \
+        | cut -d' ' -f2 \
+        )
+    and git add $gf
+end

platforms/home-manager/modules/nmasur/presets/programs/git/fish/git-commits.fish

@@ -0,0 +1,8 @@
+set commitline (git log \
+    --pretty="format:%C(auto)%ar %h%d %s" \
+    | fzf \
+        --height 50% \
+        --preview 'git show --color=always (echo {} | cut -d" " -f4)' \
+        )
+and set commit (echo $commitline | cut -d" " -f4)
+and echo $commit

platforms/home-manager/modules/nmasur/presets/programs/git/fish/git-fuzzy-branch.fish

@@ -0,0 +1,10 @@
+set -l current (git rev-parse --abbrev-ref HEAD | tr -d '\n')
+set -l branch (git branch \
+    --format "%(refname:short)" \
+    | fzf \
+        --height 50% \
+        --header="On $current, $header" \
+        --preview-window right:70% \
+        --preview 'git log {} --color=always --pretty="format:%C(auto)%ar %h%d %s"' \
+        )
+and echo $branch

platforms/home-manager/modules/nmasur/presets/programs/git/fish/git-history.fish

@@ -0,0 +1,14 @@
+if not count $argv >/dev/null
+    echo "Must provide filename."
+    return 1
+end
+set commitline ( git log \
+    --follow \
+    --pretty="format:%C(auto)%ar %h%d %s" \
+    -- ./$argv \
+    | fzf \
+        --height 100% \
+        --preview "git diff --color=always (echo {} | cut -d' ' -f4)^1..(echo {} | cut -d' ' -f4) -- ./$argv" \
+        )
+and set commit (echo $commitline | cut -d" " -f4)
+and echo $commit

platforms/home-manager/modules/nmasur/presets/programs/git/fish/git-show-fuzzy.fish

@@ -0,0 +1,6 @@
+set commitline (git log \
+   --pretty="format:%C(auto)%ar %h%d %s" \
+   | fzf \
+   )
+and set commit (echo $commitline | cut -d" " -f4 )
+and git show $commit

platforms/home-manager/modules/nmasur/presets/programs/git/fish/git.fish

@@ -0,0 +1,37 @@
+if contains f $argv
+    switch $argv[1]
+        case checkout
+            git-checkout-fuzzy
+        case add
+            git-add-fuzzy
+        case show
+            git-show-fuzzy
+        case merge
+            git-merge-fuzzy
+        case branch
+            if test "$argv[2]" = -d
+                git-delete-fuzzy
+            else if test "$argv[2]" = -D
+                git-force-delete-fuzzy
+            else
+                echo "Not a fuzzy option."
+                return 1
+            end
+        case reset
+            set commit (git-commits)
+            and if test "$argv[2]" = --hard
+                git reset --hard $commit
+            else
+                git reset $commit
+            end
+        case "*"
+            echo "No fuzzy option."
+            return 1
+    end
+else
+    if count $argv >/dev/null
+        command git $argv
+    else
+        command git status -sb
+    end
+end

platforms/home-manager/modules/nmasur/presets/programs/git/fish/uncommitted.fish

@@ -0,0 +1,9 @@
+echo "Searching git repos..." >&2
+find "$HOME/dev" -type d -name '.git' | while read dir
+    set fullPath (dirname "$dir")
+    set relativePath (echo "$fullPath" | cut -d'/' -f5-)
+    if test -n (echo (git -C "$fullPath" status -s))
+        echo "$relativePath"
+        git -C "$fullPath" status -s
+    end
+end